Arduino for STM32

Code: Select all

#include <Arduino.h>
#include <flash.h>

void sleep(uint16_t msecs);
void doread();
void dowrite();
void doerase();

#define SECT5 0x08020000UL

#define BUFSIZE 512
uint8_t buf[BUFSIZE];
bool basc = false;

void setup() {
	Serial.begin();
	pinMode(LED_BUILTIN, OUTPUT);
	memset(buf,' ',BUFSIZE);
	basc = true;
}

uint8_t nl = 0;

void loop() {
	if (nl > 5) {
		toggleLED();
		nl = 0;
	} else
		nl++;
	if(Serial.available()) {
		uint8_t c = Serial.read();
		switch(c) {
		case 'r':
			doread();
			break;
		case 'W':
			dowrite();
			break;
		case 'E':
			doerase();
			break;
		default:
			break;
		}
	}
	sleep(200);
}


void doread() {
	//Serial.write(buf,BUFSIZE);
	Serial.write((const uint8 *)SECT5,BUFSIZE);
	Serial.write('\n');
}

void dowrite() {
	uint8_t c = ' ';

	// this fills the buffer first with space ' ' and write them to flash
	// when you call this again, it fills the buffer with ascii printable characters
	// this is so that you can verify that flash and erase works in successive attempts
	// e.g. from serial monitor enter 'E' erase
	// then 'W' write
	// next 'r' read the data and print it in the serial monitor - all blanks
	// 'E' erase again
	// 'W' write again
	// 'r' read again - a block of printable ascii characters shows in the serial monitor
	if(basc) {
		for(uint16_t i=0; i<BUFSIZE; i++) {
			buf[i] = c++;
			if(c > 126)
				c = ' ';
		}
		basc = false;
	} else {
		memset(buf,' ',BUFSIZE);
		basc = true;
	}

	if (FLASH->CR & FLASH_CR_LOCK) {
		Serial.println("Unlock flash...");
		while(FLASH->SR & FLASH_SR_BSY);
		FLASH->KEYR = 0x45670123UL;
		delay(1);
		FLASH->KEYR = 0xCDEF89ABUL;
		while(FLASH->SR & FLASH_SR_BSY);
		while(FLASH->CR & FLASH_CR_LOCK);
	}
	Serial.println("Write data...");
	FLASH->CR |= FLASH_CR_PG;
	for(uint16_t i=0;i<BUFSIZE;i++) {
		while(FLASH->SR & FLASH_SR_BSY);
		*((uint8 *)SECT5+i) = buf[i];
		Serial.write('.');
	}
	Serial.println();
	Serial.println("Write complete");
	FLASH->CR &= ~FLASH_CR_PG;

}

void doerase() {
	// unlock flash
	if (FLASH->CR & FLASH_CR_LOCK) {
		Serial.println("Unlock flash...");
		while(FLASH->SR & FLASH_SR_BSY);
		FLASH->KEYR = 0x45670123UL;
		delay(1);
		FLASH->KEYR = 0xCDEF89ABUL;
		while(FLASH->SR & FLASH_SR_BSY);
		while(FLASH->CR & FLASH_CR_LOCK);
	}
	Serial.println("Erase flash...");
	uint32_t reg = FLASH->CR;
	//sector 5
	reg |= 5U << FLASH_CR_SNB_Pos;
	reg |= FLASH_CR_SER;
	reg |= FLASH_CR_STRT;
	FLASH->CR = reg;
	while(FLASH->SR & FLASH_SR_BSY);
	Serial.println("Erase complete");
}


void sleep(uint16_t msecs) {
	for(uint16_t i=0; i<=msecs; i++)
		asm("wfi");
}